Fusion et Publipostage, par l'interface et en VBA

Olivier Lebeau

Word peut se révéler un outil de choix pour la diffusion en masse de documents personnalisés. Écrire une seule lettre qui sera différente pour chaque destinataire.

- Titre : Fusion et Publipostage, par l'interface et en VBA

- Auteur : Olivier Lebeau

- Parution : 1 mars 2008

- Mise à jour : 23 mai 2012

- Licence : Copyright ® 2008 Olivier Lebeau. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Sommaire

- I. Introduction

- I-A. Les commandes

- II. Le type de document

- III. Nouveau ou document en cours

- IV. Les sources de données

- IV-A. Word

- IV-B. Excel

- IV-C. Access

- IV-D. Outlook

- IV-E. SQL Server

- IV-F. Création d'une liste

- V. Le document

- VI. L'utilisation avancée des champs

- VI-A. Les règles

- VI-A-1. Demander

- VI-A-2. Remplir

- VI-A-3. Si Alors Sinon

- VI-A-4. Numéro d'enregistrement

- VI-A-5. Numéro de séquence

- VI-A-6. Suivant

- VI-A-7. Suivant Si

- VI-A-8. Définir Signet

- VI-A-9. Sauter l'enregistrement

- VI-B. Les images

- VI-C. Le champ DataBase

- VII. Le VBA

- VII-A. Introduction

- VII-B. Ajout d'une source de données

- VII-B-1. Données SQL Server

- VII-B-2. Données Access

- VII-B-3. Données Excel

- VII-C. Ajout d'un champ de données

- VII-D. L'exécution

- VII-E. Destination du publipostage

- VII-F. Code Complet

- VII-G. Enregistrement de chaque document

- VIII. Autre méthode VBA

- VIII-A. Connexion à un SQL Server

- VIII-B. Connexion à une base de données Access

- VIII-C. Récupération de données d'une feuille Excel

- VIII-D. Utilisation des données dans un document

- VIII-D-1. Cas simple

- VIII-D-2. Cas Multiple

- IX. Liens

- X. Conclusions et remerciements

I - Introduction

Suite à de nombreuses questions liées au publipostage, j'ai décidé de me lancer dans un tutoriel. Je vais tenter d'apporter quelques éclaircissements sur les méthodes à utiliser. Certaines sont accessibles aux débutants, d'autres font appel à des techniques avancées de VBA.

Toutes les illustrations sont issues de Word 2007, mais les méthodes utilisées sont applicables aux versions antérieures.

Le publipostage est une technique qui permet de créer un grand nombre de lettres types dont le contenu est personnalisé. Les informations utilisées pour le publipostage ne se limitent pas aux données personnelles, elles peuvent être d'une tout autre nature : factures, contrats...

Dans les parties qui vont suivre, le document de fusion principal sera toujours un document Word et l'application de départ sera également Word, seules les sources de données vont changer.

I-A - Les commandes

Dans l'onglet Publipostage, Word possède une commande qui permet d'activer un assistant qui vous guidera pas à pas.

Dans la version 2007, cet assistant se présente sous la forme d'un volet.

Ce volet comporte deux parties importantes. La partie supérieure contient l'étape en cours.

La partie inférieure permet de naviguer d'une étape à l'autre.

Le ruban contient tous les outils nécessaires pour effectuer le publipostage.

Le groupe Créer

Ce groupe permet de choisir entre enveloppes et étiquettes.

Le groupe Démarrer la fusion et le publipostage

Le premier bouton du groupe permet de choisir le type de document que vous allez créer. Il ouvre une liste déroulante permettant de faire un choix. C'est également ce bouton qui donne accès à l'assistant.
Le second bouton permet la sélection des destinataires ou l'introduction d'une nouvelle liste.
Enfin, le dernier bouton permet de travailler la liste en ajoutant un tri.

Le Groupe champs d'écriture et d'insertion

Le premier bouton de ce groupe ne devient actif que si vous avez au moins un champ de fusion inséré sur votre document.
Le second permet d'insérer le bloc d'adresse.
Le troisième bouton offre la possibilité d'insérer une ligne de salutation.
Le dernier permet de choisir l'ajout d'un champ dans la liste. Vous pouvez réutiliser un champ du bloc adresse comme le prénom ou choisir un autre champ contenant d'autres données.

Finalement, il est parfois utile de prévisualiser les résultats avant de lancer l'impression ou l'envoi :

Le groupe Aperçu des résultats

Dans certains cas de figure, la prévisualisation n'est pas correcte, seul le résultat final l'est.

II - Le type de document

Pour le type de document, Word est plein de ressources.

ou encore

Ces choix correspondent à : une lettre, par exemple si votre activité change d'adresse et que vous souhaitez prévenir vos clients, un message électronique comme une "News Letter", parallèlement à l'édition de lettres vous pouvez y associer des enveloppes, faire des planches d'étiquettes ou finalement pour "créer" un répertoire (répertoire téléphonique).

III - Nouveau ou document en cours

Vous pouvez créer un document fondé sur le document en cours d'édition, créer un nouveau document fondé sur un modèle existant ou créer un nouveau document d'après un document existant.

Cette étape ne devrait normalement pas poser de problème.

IV - Les sources de données

Nous allons parcourir quelques types de sources de données utilisables avec Word.

Une fois la source de données choisie, si vous enregistrez votre document, vous obtenez un document principal de fusion.

IV-A - Word

Pour la source de données, nous pouvons utiliser un document Word. Il est beaucoup plus aisé d'utiliser un tableau pour gérer vos données. Si vous respectez certaines conventions, il sera d'autant plus facile d'utiliser ce document.

Liste préformatée d'un tableau

- Nom

- Prénom

- Adresse

- No

- Cp

- Ville

- Tel

La liste peut aussi être formatée en CSV (Valeurs Séparées par des Virgules).

Il ne reste qu'à choisir le document Word contenant la liste.

IV-B - Excel

Cette liste peut également être une feuille Excel.

On choisit cette liste de la même manière que pour un fichier Word.

Et votre liste peut se trouver sur n'importe quelle feuille du classeur.

Si votre première ligne n'est pas une ligne de données, vous devez le préciser à l'ouverture.

Il est même possible d'utiliser une plage de données.

IV-C - Access

L'utilisation d'une base de données Access pour la fusion et le publipostage est bien évidemment possible.
Dans l'onglet publipostage, après un clic le bouton Sélection de destinataires, choisissez Utiliser la liste existante.

Vous obtenez alors une boîte de dialogue permettant de choisir un fichier, le répertoire par défaut est le répertoire contenant les informations sur les sources de données.

Si votre base de données possède plusieurs tables, vous pouvez choisir la table qui contient vos adresses ou données pour le publipostage. Les requêtes sont également proposées.

IV-D - Outlook

Outlook contenant aussi des adresses, vous pouvez sélectionner le carnet d'adresses Outlook pour un publipostage. Cette méthode se révèle très intéressante si vous désirez faire un e-mailing.

Si vous possédez plusieurs carnets d'adresses, vous aurez le choix.

IV-E - SQL Server

Pour cette partie, nous allons utiliser une source de données située sur une base SQL (SQL Server 2005 Express). J'ai choisi cette version parce qu'elle est disponible pour tous du fait de sa gratuité. Pour lier des données issues d'une base de données SQL Server, on procède de la même manière que pour les autres sources de données.

Tous les exemples ont été réalisés à partir de SQL Server Express 2005.

IV-F - Création d'une liste

Si vous n'avez pas encore de liste et que vous désirez créer une nouvelle liste, Word possède un outil qui va vous permettre de saisir une liste utilisable dans une fusion ou un publipostage.

Vous ouvrez un formulaire qui va vous permettre d'entrer des données.

Ce formulaire sommaire contient cependant tous les champs nécessaires pour faire votre publipostage. Si les colonnes proposées ne vous conviennent pas, vous avez la possibilité de les personnaliser.

Dès que votre liste est terminée, le clic sur le bouton OK ouvre une boîte de dialogue vous demandant d'enregistrer vos données. Le seul format proposé est le format *.mdb qui est le format de base de données des versions antérieures d'Access.

Par défaut, Word contient les outils minimums pour l'utilisation et la création d'une base de données Access.

V - Le document

Vous pouvez éditer votre document à n'importe quelle étape du publipostage. Il existe des champs par défaut et des blocs pour vous faciliter la tâche. Le plus intéressant est le bloc d'adresse.

Si vous utilisez le bouton Bloc d'adresses, vous pouvez visualiser le résultat obtenu et parcourir les différents enregistrements qui constituent votre liste.

Vous avez également la possibilité d'insérer un champ contenant des données autres que le bloc adresse.

Lorsque vous avez choisi un champ, il s'affiche dans votre document entouré de guillemets.

Si vous voulez visualiser le contenu de votre champ, vous devez faire un clic droit sur le champ et choisir "Basculer les codes de champ".

Vous obtenez alors l'affichage du code du champ de fusion et de publipostage.

Après avoir inclus au moins un champ dans votre document, vous pouvez visualiser l'aspect final de votre document. Vous avez à votre disposition un groupe de contrôle pour vous y aider.

VI - L'utilisation avancée des champs

Jusqu'à présent, nous avons utilisé les champs de publipostage de façon très simple. Word permet une utilisation un peu plus avancée des champs.

Pour l'utilisation avancée du publipostage, je vous conseille de modifier les paramètres d'affichage de votre document.
Bouton Office, Options Word

Dans la partie Options Avancées et Afficher le contenu du document, choisissez Afficher les codes de champ plutôt que leurs valeurs.

La combinaison de touches Alt + F9 produit le même résultat.

VI-A - Les règles

Word offre la possibilité de fixer des règles pour le publipostage.

Toutes les règles ne sont pas compatibles entre elles.

VI-A-1 - Demander

Dans le cadre d'un publipostage, ce champ n'a pas de fonction immédiate et ne doit pas être utilisé seul. Je vous conseille de l'utiliser avec un champ REF.

Insérer le champ demander

Vous ouvrez alors une boîte de dialogue.

Le remplissage

1. Le nom du signet qui sera inséré.

2. Le titre de la boîte de dialogue (je vous conseille d'y mettre votre question).

3. Le message par défaut (si vous n'entrez rien, ce sera ce texte qui sera inséré dans le signet).

4. Si cette option n'est pas cochée, Word vous demandera un texte pour chaque document.

La boîte remplie

Si vous n'utilisez pas de champ REF, vous ne verrez pas la valeur entrée dans votre document final.

Avec champ REF

VI-A-2 - Remplir

En comparaison avec le champ précédent, le champ remplir ne se retrouve pas dans un signet. Il n'est donc pas possible de l'utiliser avec le champ REF. Le texte entré est intégré à votre document. Ce champ pourrait être utilisé pour renseigner le nom du correspondant qui a publié les documents.

Le champ remplir

Le champ contenant votre invite et ses commutateurs

Le champ Remplir

VI-A-3 - Si Alors Sinon

Dans les règles, la règle la plus intéressante est Si... Alors... Sinon. Si vous souhaitez utiliser des articles ou qualificatifs pour différencier les hommes des femmes, par exemple Cher Marcel ou Chère Marie, vous devriez ajouter autant de champs dans votre base de données que de qualificatifs ou articles que vous pensez devoir utiliser.
Cette règle assez simple permet de faire un choix en fonction d'un champ de votre base de données. Imaginez que vous ajoutiez le champ sexe dans vos données, vous pouvez faire ce choix à n'importe quel endroit de votre document.

Vous obtiendrez une boîte de dialogue :

Et comme résultat :

Le contenu du champ si vous l'affichez sera celui-ci

On se trouve avec un champ Si

VI-A-4 - Numéro d'enregistrement

Ce champ ajoute le numéro de l'enregistrement au document. Si vous désirez numéroter vos lettres, ce champ est tout indiqué.

Numéro d'enregistrement

Le champ

VI-A-5 - Numéro de séquence

La valeur obtenue sera identique au champ Numéro d'enregistrement si vous utilisez tous les enregistrements. Si vous filtrez les enregistrements, ce numéro sera différent.

Numéro de séquence

Le champ

VI-A-6 - Suivant

Ce champ va passer à l'enregistrement suivant. C'est ce champ qui est utilisé par Word si vous utilisez le publipostage pour la génération d'un répertoire.

Pour que cette commande fonctionne, elle ne peut être placée devant le premier champ de votre publipostage et elle n'agit que pour le champ qui la suit directement.

VI-A-7 - Suivant Si

Ce champ va fusionner dans le même document l'enregistrement suivant si la condition n'est pas remplie, si la condition est remplie, on passe alors au document suivant. On utilise ce champ lorsque plusieurs enregistrements composent les données à utiliser pour un même document de publipostage. C'est le cas pour des factures.
L'inconvénient, c'est qu'il est impératif de connaître le nombre d'occurrences que l'on va rencontrer. Nous verrons plus loin dans ce tutoriel comment utiliser une méthode bien plus souple en VBA.

VI-A-8 - Définir Signet

Ce champ permet d'affecter une valeur à un signet. Cette valeur peut être directement intégrée au champ.

{ SET Monsignet "MaValeur"}

Dans ce cas, le signet prendra la valeur "MaValeur". Pour afficher le contenu du signet, vous devrez utiliser un champ REF.

{ REF Monsignet }

On peut aussi lui affecter la valeur d'un champ de publipostage. Cette utilisation peut être très utile si vous avez un document de plusieurs pages et que vous souhaitez afficher au début de chaque page le nom du destinataire.

{ SET Monsignet { MERGEFIELD Nom } }
{ REF Monsignet }

VI-A-9 - Sauter l'enregistrement

Ce champ permet d'éviter l'impression de certains enregistrements s'ils ne répondent pas à certaines conditions. L'exemple le plus simple est l'envoi de lettre uniquement aux femmes. Si c'est un homme, l'enregistrement doit être ignoré. La fonction de ce champ est identique au filtre.

Ne soyez pas surpris, cette clause de rejet n'affecte que le publipostage et pas son aperçu.

On obtient ce critère de sélection avec la méthode suivante :

Le résultat obtenu :

Si votre affichage ne ressemble pas à l'illustration, utilisez la combinaison de touches Alt + F9 pour basculer l'affichage des champs et n'oubliez pas de refaire cette opération pour annuler l'effet.

Le code :

{ SKIPIF { MERGEFIELD Sexe } = "H" }

VI-B - Les images

Dans l'utilisation du publipostage, on ne trouve pas souvent de renseignement sur l'affichage des images.
Il est possible d'obtenir pour chaque enregistrement une image différente, imaginez un répertoire où vous pourriez associer une photo à son propriétaire. Si vous décortiquez un champ d'insertion d'image dans Word, vous obtenez ceci :

{ INCLUDEPICTURE  "c:\\temp\\a.jpg"  \* MERGEFORMAT }

La méthode pour y parvenir est la suivante : dans l'onglet Insérer, le bouton QuickPart et la commande Champ.

Choisissez champ Inclureimage.

Et remplissez avec le chemin de votre image.

Il ne nous reste plus que l'utilisation d'un champ de publipostage pour remplir le champ INCLUDEPICTURE.

{ INCLUDEPICTURE  { MERGEDFIELD Path }  \* MERGEFORMAT }

Les commutateurs utilisables sont identiques aux commutateurs des champs.
Le champ InclureImage

Lors de l'édition du champ, on se rend compte que le chemin du fichier doit comporter des doubles antislashs au lieu des simples antislashs. Pour obtenir une insertion d'image lors d'un publipostage, nous devons donc ajouter un champ dans l'enregistrement qui contiendra le chemin de l'image mais avec des doubles antislashs.

Le chemin normal

C:\Temp\a.jpg

Le chemin à utiliser

C:\\Temp\\a;jpg

L'insertion des images ne se produit que lors de la fusion, le mode prévisualisation ne permet pas l'affichage des images. Pour que toutes les images soient mises à jour, utilisez la combinaison Ctrl + A pour sélectionner tout le document et ensuite la touche F9 pour mettre les champs à jour.

VI-C - Le champ DataBase

Si vous souhaitez utiliser un groupement d'enregistrements pour votre publipostage comme le sont les factures. Si vous ne souhaitez pas passer par du publipostage, il est possible d'utiliser un champ DataBase ou base de données.

Le résultat de ce champ est basé sur une requête SQL.

Notre "Base de données est un fichier Excel contenant deux feuilles, l'une avec les données des clients et la seconde avec des données multiples par client.

Feuille Clients : No ; Nom ; Prénom.

Feuille Achats : Client ; NoArticle;Dénomination ; Quantité

Le champ No de la feuille Clients correspond au champ Client de la feuille Achats.

Commençons par un publipostage simple où la source de données sera la feuille clients de notre classeur.

Il suffit d'ajouter les champs du publipostage au document.

Insérons ensuite un champ Base de Données.

Vous obtiendrez une boîte de dialogue vous permettant de choisir le champ que vous souhaitez insérer.

Cliquez sur le bouton "Insérer une base de données".

«

En cliquant sur obtenir les données, vous ouvrez une boîte de dialogue permettant de choisir la source de données que vous souhaitez utiliser.

J'ai pris comme source de données un fichier Excel, ce fichier contient trois feuilles, mais seules deux d'entre elles contiennent des données. C'est le nom des feuilles qui apparaît dans la boîte de dialogue. Nous en avons déjà utilisé une (Clients), nous allons utiliser la seconde (Achats).

Dans mon fichier Excel, la première ligne contient les en-têtes de colonnes

Cette opération va insérer les données dans le document Word.

Cette étape est très importante, si vous ne cochez pas "Insérer en tant que champ", les données seront insérées sous la forme d'un tableau qui sera inutilisable. En cochant cette case, les données ne sont pas directement insérées, mais c'est un champ contenant le chemin du fichier et une requête SQL qui sera présent dans le document. (On affiche le contenu du champ avec la combinaison de touches Shift + F9.)

La partie du champ surlignée en bleu correspond à la Sentence SQL qui sera exécutée pour trier les données. Si nous ne modifions pas ce SQL, toutes les données de la seconde feuille seront insérées. Nous devons donc modifier ce SQL pour qu'il n'affiche que les données relatives à l'enregistrement en cours.

Les commandes SQL sont relativement simples à manipuler, surtout lorsqu'il ne s'agit que de sélectionner les données.

Ci-dessous, un exemple d'une sentence SQL pour la sélection des données.

SQL

SELECT * FROM "Table" WHERE Champ = maValeur"

Dans cette sentence, "SELECT *" signifie que tous les champs seront pris en compte pour le résultat, si le résultat ne doit contenir que quelques champs, ils seront mentionnés à la place du symbole *. La partie contenant FROM mentionne la table de laquelle seront extraites les données.

Si nous reprenons notre exemple, nous obtenons ceci :

Nous avons maintenant un champ de publipostage inclus dans le champ base de données.

Comme à chaque fois, la prévisualisation des résultats ne convient pas vraiment, il faut l'actualiser pour chaque enregistrement, seul le résultat final est utilisable.

VII - Le VBA

VII-A - Introduction

La commande pour la fusion et le publipostage en Word est MailMerge, et l'exécution de la fusion avec Execute.

ActiveDocument.MailMerge.Execute

Pour que cette commande ne lève pas d'erreur, certaines conditions doivent être remplies. La principale : le document doit être un document principal de fusion et publipostage.

Un document principal de fusion est un document qui possède une source de données associée.

Pour savoir si votre document est un document principal de fusion, vous pouvez faire le test suivant :

Sub TestDocPrincipal()
If ActiveDocument.MailMerge.State = 2 Then MsgBox "Le document est un document principal de fusion !"
End Sub

Valeur

Nom

Description

0

wdNormalDocument

Le document n'est pas inclus dans un processus de fusion et publipostage.

1

wdMainDocumentOnly

Document de base sans donnée jointe.

2

wdMainAndDataSource

Document de base avec une source de données jointe.

3

wdMainAndHeader

Document de base avec un fichier d'en-tête.

4

wdMainAndSourceAndHeader

Document de base avec une source de données et un fichier d'en-tête joints.

5

wdDataSource

Source de données sans document de base.

Nous pourrions même envisager de faire une fonction pour tester l'état du document.

Routine d'appel

Sub TestEtatDoc()
MsgBox EtatDocument (ActiveDocument.MailMerge.State)
End Sub

Fonction

Function EtatDocument( btEtat As Byte ) As String
Select Case btEtat
Case 0
EtatDocument = "Le document n'est pas inclus dans un processus de fusion et publipostage."
Case 1
EtatDocument = "Document de base sans donnée jointe."
Case 2
EtatDocument = "Document de base avec une source de données jointe."
Case 3
EtatDocument = "Document de base avec un fichier d'en-tête."
Case 4
EtatDocument = "Document de base avec une source de données et un fichier d'en-tête joints."
Case 5
EtatDocument = "Source de données sans document de base."
End Select
End Function

VII-B - Ajout d'une source de données

Si votre document n'est pas un document principal de fusion, vous devez si vous désirez faire du publipostage lui adjoindre une source de données. La méthode pour l'ajout de données à votre document est OpenDataSource.

Ajout de données

Sub DocAjoutSource()
ActiveDocument.MailMerge.OpenDataSource .....
End Sub

VII-B-1 - Données SQL Server

Pour ajouter des données d'une base SQL Server, vous devez utiliser le chemin du fichier se trouvant dans le répertoire "Mes sources de données".

Si par curiosité vous ouvrez ce fichier "*.ODC" à l'aide du Bloc-notes, vous verrez que vous êtes en présence d'un fichier XML contenant des données et des scripts.

Données SQL Server

Sub DocAjoutSource()
ActiveDocument.MailMerge.OpenDataSource _
Name:="C:\Documents and Settings\UserName\Mes documents\Mes sources de données\OLIVIERPC_SQLEXPRESS DBSQL Table1.odc"
End Sub

Après exécution, vous pouvez vérifier que les données sont "liées" au document dans l'onglet publipostage et le bouton Modifier la liste des destinataires.

VII-B-2 - Données Access

La méthode pour lier des données Access ne diffère pas de la méthode utilisée pour des données SQL Server. Mais au lieu d'utiliser le fichier de connexion à SQL Server, nous allons utiliser le nom du fichier Access.

Données Access

Sub DocAjoutSource()
ActiveDocument.MailMerge.OpenDataSource _
Name:="C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\adresses.mdb"
End Sub

La même manipulation qu'au paragraphe 7-B-1, vous permettra de vérifier que les données sont liées au document.

VII-B-3 - Données Excel

Une fois de plus, la méthode pour utiliser une source de données basée sur un fichier Excel est la même que pour les autres fichiers de données.

Données Excel

Sub DocAjoutSource()
ActiveDocument.MailMerge.OpenDataSource Name:="C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\adresses.xlsx"
End Sub

Avec les mêmes manipulations, on peut vérifier que les données sont correctement liées au document.

VII-C - Ajout d'un champ de données

Si vous n'avez pas défini de champ de sortie dans votre document, vous pouvez les insérer par le code. Quelle que soit la source choisie, la méthode pour insérer des champs reste la même.

Insertion d'un champ

ActiveDocument.Fields.Add Range:=Selection.Range, Type:=wdFieldMergeField, Text:="""Nom"""

La méthode pour insérer les champs et le texte est assez simple, il suffit d'écrire les lignes de code les unes sous les autres.

Insertion de champs et de texte

ActiveDocument.Fields.Add Range:=Selection.Range, Type:=wdFieldMergeField, Text:="""Nom"""
Selection.TypeText vbCrLf & " Je viens de mettre le nom " & vbCrLf
ActiveDocument.Fields.Add Range:=Selection.Range, Type:=wdFieldMergeField, Text:="""Prénom"""

Vous avez aussi la possibilité d'insérer votre champ sur un signet.

Insérer sur signet

ActiveDocument.Fields.Add Range:=Bookmarks(1).Range, Type:=wdFieldMergeField, Text:="""Nom"""

VII-D - L'exécution

Il ne reste qu'à exécuter le publipostage. La méthode Execute va le faire et créer un nouveau document.

Exécution du publipostage

AcriveDocument.MailMerge.Execute

VII-E - Destination du publipostage

Le publipostage permet d'envoyer le ou les documents vers une destination. Cette destination peut être un nouveau document, une imprimante, un e-mail ou un FAX.

ActiveDocument.MailMerge.Destination = wdSendToNewDocument

Paramètre

Destination

wdSendToNewDocument

Le publipostage va se faire vers un nouveau document

wdSendToPrinter

Le résultat du publipostage sera directement envoyé sur l'imprimante

wdSendToEmail

Le résultat sera un envoi par e-mail du document

wdSendToFax

Le résultat du publipostage sera envoyé par FAX si un FAX est installé sur le PC

Si vous utilisez wdSendToEmail ou wdSendToFax , vous devez vous assurer que le champ contenant l'adresse e-mail ou le numéro de fax est correctement renseigné.

VII-F - Code Complet

Voilà le code complet des paragraphes précédents avec l'utilisation des signets.

Code Complet avec signets

Sub DocPubliposte()
ActiveDocument.MailMerge.OpenDataSource _
Name:="C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\OLIVIERPC_SQLEXPRESS DBSQL Table1.odc"

ActiveDocument.Fields.Add Range:=Bookmarks(1).Range, Type:=wdFieldMergeField, Text:="""Nom"""
ActiveDocument.Fields.Add Range:=Bookmarks(2).Range, Type:=wdFieldMergeField, Text:="""Prénom"""
ActiveDocument.MailMerge.Execute

End Sub

Ce code s'il est utilisé plusieurs fois à la suite va insérer plusieurs fois les champs de publipostage. Il est donc préférable de l'utiliser lors de la création d'un document. Pour les utilisations ultérieures du document, il est préférable de se contenter de l'Exécution.

VII-G - Enregistrement de chaque document

Il arrive fréquemment que l'on cherche à enregistrer les documents issus du publipostage dans des fichiers séparés. Les méthodes offertes par Word au travers de l'interface graphique ne permettent pas d'avoir un document par enregistrement ou ligne de données.

En exécutant le publipostage par le code, vous pouvez enregistrer chaque document avec comme nom les données contenues dans votre base de données.

Le principe est assez simple, on va récupérer le nombre d'enregistrements contenus dans la source de données (iR) et dans une boucle, nous allons parcourir ces enregistrements les uns après les autres.
For i = 1 To iR
Pour utiliser un enregistrement précis, nous allons utiliser i pour définir le premier et le dernier enregistrement de la série, ce qui ne nous donnera qu'un seul enregistrement.

Sub TestPublipost()
' Déclaration des variables
Dim iR As Integer
Dim i As Integer
Dim oDoc As Document
Dim DocName As String
Dim oDS As MailMergeDataSource

' Affectation des objets
Set oDoc = ActiveDocument
Set oDS = oDoc.MailMerge.DataSource

iR = oDoc.MailMerge.DataSource.RecordCount
Debug.Print iR
For i = 1 To iR
With oDoc.MailMerge
'Définition du premier et dernier enregistrement
.DataSource.FirstRecord = i

.DataSource.LastRecord = i
' Envoi des données dans un nouveau document
.Destination = wdSendToNewDocument
' Exécution du publipostage
.Execute
' Actualisation de l'enregistrement pour la sauvegarde
.DataSource.ActiveRecord = i
'Utilisation de deux champs pour obtenir le nom du document
DocName = .DataSource.DataFields(2).Value
DocName = DocName & "-" & .DataSource.DataFields(3).Value
Debug.Print DocName; i
End With
' Sauvegarde du document publiposté
With ActiveDocument
.SaveAs "c:\temp\" & DocName & ".doc"
.Close
End With
Next i
End Sub

Les différents Debug.Print utilisés dans le code servent à "monitorer" le déroulement de la procédure.

La variable DocName va recevoir le nom de sauvegarde du document. Ce nom sera la concaténation de deux valeurs de champ, dans le code ci-dessus, nous utilisons la donnée du deuxième et du troisième champ.
DocName = .DataSource.DataFields(2).Value
DocName = DocName & "-" & .DataSource.DataFields(3).Value

Finalement, c'est ce morceau de code qui va enregistrer le document dans le répertoire C:\temp\

With ActiveDocument
.SaveAs "c:\temp\" & DocName & ".doc"
.Close
End With

VIII - Autre méthode VBA

La méthode VBA que nous venons de voir utilise les fonctionnalités du Publipostage de Word. Il est possible d'obtenir un résultat similaire sans utiliser la fonction Publipostage de Word.
Nous allons aborder ce sujet dans ce chapitre.

Nous allons aborder la connexion avec des données à un SQL server, la connexion avec des données Access et terminer par la récupération de données d'un classeur Excel.

VIII-A - Connexion à un SQL Server

Vous devez ajouter la référence Microsoft ActiveX Data Object à votre projet.

Pour les raisons énoncées un peu plus haut, j'ai utilisé SQL Server 2005 version Express.

La première chose à connaître est le nom de votre serveur SQL. Dans l'exemple qui suit, c'est le nom par défaut donné au serveur lors de son installation.

Le lien ci-dessous vous donne une vue d'ensemble sur le SQL Server 2005.
Présentation de SQL Server 2005

Si vous suivez le lien ci-dessous, vous trouverez un article sur l'utilisation de Recordset ADO.
Comprendre les Recordset ADO

Le principe reste assez simple, il faut en premier lieu ouvrir une connexion vers le Serveur pour ensuite en extraire les données avec une commande SQL.

Connexion à un serveur SQL

Sub connexionSQL()
Dim rs As ADODB.Recordset
Dim stCon As ADODB.Connection
Dim Utili As String
Dim mdp As String
Utili = ""
mdp = ""

'Création d'un objet ADO
Set stCon = New ADODB.Connection
'Accès aux données
With stCon
.ConnectionString = "UID=" & Utili & ";PWD=" & mdp & ";" & "DRIVER={SQL Server};Server=" _
& "OLIVIERPC\SQLEXPRESS" & ";Database=" & "DBSQL" & ";"
.Open
End With
'Création d'un objet Recordset (jeu d'enregistrements)
Set rs = New ADODB.Recordset

rs.Open "SELECT * FROM Table1", stCon
'Boucle pour parcourir les enregistrements et afficher leur contenu
'dans la fenêtre d'exécution.
While Not rs.EOF
Debug.Print rs.Fields(2).Value
rs.MoveNext
Wend
'libération des objets
stCon.Close
set stCon = Nothing
Set rs = Nothing

End Sub

Si vous avez correctement utilisé le code, vous devriez avoir une liste avec le contenu du troisième champ de votre table.

VIII-B - Connexion à une base de données Access

Vous devez ajouter la référence Microsoft DAO Object Library à votre projet

Le principe pour accéder aux données contenues dans une base de données Access est sensiblement le même que pour un Serveur SQL avec du ADO.

Comme nous allons utiliser du DAO, je vais vous donner un lien sur l'utilisation du DAO.
Définition et manipulation de données avec DAO

Récupération des données Access

Sub ConnexionDBAccess()
'Déclaration des variables
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim sql As String
'Affectation de la sentence SQL
sql = "SELECT * From T_Adresses"
'Affectation des Objets d'Access aux données
Set db = DBEngine.OpenDatabase("C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\DB_Publipostage.mdb")
Set rs = db.OpenRecordset(sql)
'Boucle pour la récupération des données
While Not rs.EOF
Debug.Print rs.Fields(2)
rs.MoveNext
Wend
'Libération des objets
rs.Close
db.Close

Set rs = Nothing
Set db = Nothing

End Sub

Comme pour le paragraphe précédent, vous devriez avoir une liste avec le contenu du troisième champ de votre table.

VIII-C - Récupération de données d'une feuille Excel

Vous devez ajouter la référence Microsoft Excel Object Library à votre projet

Comparée aux deux méthodes précédentes, la récupération de données contenues dans un classeur Excel est un peu différente.
Nous allons ouvrir le classeur, obtenir le nombre de lignes (iR) et le nombre de colonnes (iC) pour ensuite dans une double boucle récupérer les données des cellules en fonction de leur adresse.

Extraction des données d'une feuille Excel

Sub donneeAvecExcel()
'Déclaration des variables
Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSh As Excel.Worksheet
Dim iR As Integer
Dim iC As Integer
Dim i As Integer, j As Integer

'Affectation des données aux variables
Set xlApp = New Excel.Application
Set xlWb = xlApp.Workbooks.Open("C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\adresses.xlsx")
Set xlSh = xlWb.Worksheets(1)
'Récupération du nombre de lignes et de colonnes
iR = xlSh.UsedRange.Rows.Count
iC = xlSh.UsedRange.Columns.Count
'Boucle pour adresser les cellules contenant des données
'en excluant la première ligne qui contient les titres
For i = 2 To iR
For j = 1 To iC
Debug.Print xlSh.Cells(i, j)
Next j
Next i

xlWb.Close
xlApp.Quit
Set xlSh = Nothing
Set xlWb = Nothing
Set xlApp = Nothing

End Sub

VIII-D - Utilisation des données dans un document

Maintenant que nous avons vu comment extraire des données, nous allons les utiliser. La manipulation reste la même, que les données soient issues d'une base de données SQL Server, d'une base de données Access ou d'une feuille Excel.
Le principe que nous allons mettre en œuvre est relativement simple, les données récupérées seront envoyées vers des signets que nous aurons mis dans notre document. L'utilisation de signets est la plus souple, elle permet d'insérer les données à des endroits précis de notre document.

Pour insérer des données sur un signet, c'est assez simple :

Insertion de données sur un signet

ActiveDocument.Bookmarks(1).Range.Text = "La Donnée"

Le principe est relativement simple, dans l'exemple que je viens de donner, la donnée est fixe. Mais on peut utiliser une donnée extraite :

ActiveDocument.Bookmarks(1).Range.Text = xlSh.Cells(i, j)

Voilà pour l'insertion de données.

VIII-D-1 - Cas simple

Nous allons distinguer le cas simple (un enregistrement par document : une lettre) du cas multiple (plusieurs enregistrements par document : une facture). Cet enregistrement peut contenir le nom du fichier, son répertoire de sauvegarde, etc.
Pour les données, il suffit de les transférer vers le document dans des signets.

Dans les paragraphes précédents, nous avons vu comment extraire les données. Nous allons aller un peu plus loin et traiter les données.

Traitement des données

While Not rs.EOF
'Traitement des données
rs.MoveNext
Wend

Nous allons remplir cette boucle avec le traitement des données. Nous allons utiliser les champs pour les envoyer dans le document.
Pour le code, je vais utiliser la connexion à une base de données Access. Je suppose que pour chaque document, il faut utiliser le nom issu des données et la date au format "aa-mm-jj" comme nom de document.

Le code avec le transfert de données

Sub ConnexionDBAccess()
'Déclaration des variables
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim oDoc As Document
Dim sql As String
'Affectation de la sentence SQL
sql = "SELECT * From T_Adresses"
'Affectation des Objets d'Access aux données
Set db = DBEngine.OpenDatabase("C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\DB_Publipostage.mdb")
Set rs = db.OpenRecordset(sql)
'Boucle pour la récupération des données
While Not rs.EOF
'Affectation d'un objet document à la variable document
Set oDoc = Documents.Add("C:\Documents and Settings\Olivier\Application Data\Microsoft\Templates\pub.dotm")
'Écriture des données sur les signets
oDoc.Bookmarks(1).Range.Text = rs.Fields(1)
oDoc.Bookmarks(2).Range.Text = rs.Fields(2)
oDoc.Bookmarks(3).Range.Text = rs.Fields(3)
'Sauvegarde du document
oDoc.SaveAs "c:\temp\" & rs.Fields(1) & "-" & Format(Date, "yy-mm-dd") & ".docx"
'Libération de l'objet document
oDoc.Close
Set oDoc = Nothing

rs.MoveNext
Wend
'Libération des objets
rs.Close
db.Close

Set rs = Nothing
Set db = Nothing

End Sub

Dans l'exemple ci-dessus, j'ai utilisé les numéros des champs et des signets par facilité, mais il est possible d'utiliser leur nom.

Le traitement avec une feuille Excel

Sub donneeAvecExcel()
'Déclaration des variables
Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSh As Excel.Worksheet
Dim iR As Integer
Dim i As Integer, j As Integer
Dim oDoc As Document

'Affectation des données aux variables
Set xlApp = New Excel.Application
Set xlWb = xlApp.Workbooks.Open("C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\adresses.xlsx")
Set xlSh = xlWb.Worksheets(1)
'Récupération du nombre de lignes et de colonnes
iR = xlSh.UsedRange.Rows.Count

' Récupération des données de la feuille pour les injecter dans le document.
For i = 2 To iR
Debug.Print xlSh.Cells(iR, 2); iR
Set oDoc = Documents.Add("C:\Documents and Settings\Olivier\Application Data\Microsoft\Templates\pub.dotm")
oDoc.Bookmarks(1).Range.Text = xlSh.Cells(i, 1)
oDoc.Bookmarks(2).Range.Text = xlSh.Cells(i, 2)
oDoc.Bookmarks(3).Range.Text = xlSh.Cells(i, 3)
oDoc.SaveAs "c:\temp\" & xlSh.Cells(i, 2) & "-" & Format(Date, "yy-mm-dd") & ".docx"
oDoc.Close
Set oDoc = Nothing
Next i

xlWb.Close
xlApp.Quit
Set xlSh = Nothing
Set xlWb = Nothing
Set xlApp = Nothing

End Sub

Dans le premier code utilisé avec une feuille Excel, nous avons tenu compte du nombre de colonnes. Lors du publipostage, ce nombre de colonnes n'est plus utilisé.

Il bien évidemment possible d'imprimer le document avant la sauvegarde.

Pour l'impression

oDoc.SaveAs "c:\temp\" & xlSh.Cells(i, 2) & "-" & Format(Date, "yy-mm-dd") & ".docx"
oDoc.PrintOut
oDoc.Close

VIII-D-2 - Cas Multiple

Par cas multiple, je suppose plusieurs enregistrements ou lignes pour un même document, comme pour une facture. On peut y arriver par les champs de fusion et de publipostage, mais avec certaines restrictions, on doit connaître le nombre maximum d'occurrences avant fusion. Il n'est pas possible d'insérer les données dans une table.

Pour la récupération des données, le principe reste identique, ce qui change, c'est le traitement des données. Dans cette partie nous allons simplement nous attarder sur le traitement des données et non plus sur leur récupération.
Pour chaque enregistrement ou ligne, nous allons vérifier si une des valeurs est identique à la ligne précédente on ajoute une ligne au document, si la valeur est différente, on crée un nouveau document et on ferme le précédent.
Vous l'aurez compris, nous allons utiliser des structures conditionnelles dans notre traitement.

Voilà un exemple de données

IdFact

NoFacture

IdClient

Produit

Qantité

1

1

1

Ballon

10

2

1

1

Filet

1

3

2

1

Vélo

1

4

2

1

Casque

1

5

3

2

Ballon

5

Créez un modèle contenant des signets (au moins 3) et un tableau avec une ligne et deux colonnes.

Dans notre traitement, nous allons comparer les numéros de facture qui devraient être le critère de regroupement.

Publipostage Multiple

Sub donneeAvecExcel()
On Error GoTo GestErr
'Déclaration des variables
Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSh As Excel.Worksheet
Dim iR As Integer
Dim i As Integer, j As Integer
Dim oDoc As Document
Dim NoFact As Integer
Dim oTbl As Table
Dim stDocName As String

'Affectation des données aux variables
Set xlApp = New Excel.Application
Set xlWb = xlApp.Workbooks.Open("C:\Documents and Settings\Olivier\Mes documents\Mes sources de données\adresses.xlsx")
Set xlSh = xlWb.Worksheets(2)
'Récupération du nombre de lignes et de colonnes
iR = xlSh.UsedRange.Rows.Count
NoFact = 0

' Récupération des données de la feuille pour les injecter dans le document.
For i = 2 To iR
If NoFact <> xlSh.Cells(i, 2) Then
stDocName = "c:\temp\" & xlSh.Cells(i, 2) & "-" & Format(Date, "yy-mm-dd") & ".docm"
oDoc.Close
Set oDoc = Documents.Add("C:\Documents and Settings\Olivier\Application Data\Microsoft\Templates\pub1.dotm")
oDoc.Bookmarks(1).Range.Text = xlSh.Cells(i, 1)
oDoc.Bookmarks(2).Range.Text = xlSh.Cells(i, 2)
oDoc.Bookmarks(3).Range.Text = xlSh.Cells(i, 3)
Set oTbl = oDoc.Tables(1)
oTbl.Rows.Add
oTbl.Rows.Last.Cells(1).Range.Text = xlSh.Cells(i, 4)
oTbl.Rows.Last.Cells(2).Range.Text = xlSh.Cells(i, 5)
Set oTbl = Nothing
oDoc.SaveAs stDocName
'Affectation du nouveau numéro de facture pour la comparaison
NoFact = xlSh.Cells(i, 2)
Else
Set oTbl = oDoc.Tables(1)
oTbl.Rows.Add
oTbl.Rows.Last.Cells(1).Range.Text = xlSh.Cells(i, 4)
oTbl.Rows.Last.Cells(2).Range.Text = xlSh.Cells(i, 5)
Set oTbl = Nothing
oDoc.Save
End If
Next i

oDoc.Close

Set oDoc = Nothing
GestErr:
'Si pas de document ouvert on fait un resume next
If Err.Number = 91 Then Resume Next
Debug.Print "Erreur : " & Err.Number & Err.Description
xlWb.Close
xlApp.Quit
Set xlSh = Nothing
Set xlWb = Nothing
Set xlApp = Nothing

End Sub

Si nous détaillons un peu le code.

oDoc.Close

On ferme le document, si aucun document n'est affecté à la variable oDoc, on déclenche une erreur. Cette erreur est gérée par :

On Error GoTo GestErr

et par :

GestErr:
'Si pas de document ouvert on fait un resume next
If Err.Number = 91 Then Resume Next

En effet, si aucun objet n'est affecté, alors une erreur 91 intervient. On en connait la raison, on peut donc continuer la procédure avec Resume Next.

Set oDoc = Documents.Add("C:\Documents and Settings\Olivier\Application Data\Microsoft\Templates\pub1.dotm")
oDoc.Bookmarks(1).Range.Text = xlSh.Cells(i, 1)
oDoc.Bookmarks(2).Range.Text = xlSh.Cells(i, 2)
oDoc.Bookmarks(3).Range.Text = xlSh.Cells(i, 3)

Cette partie a déjà été utilisée plus tôt !

Set oTbl = oDoc.Tables(1)
oTbl.Rows.Add
oTbl.Rows.Last.Cells(1).Range.Text = xlSh.Cells(i, 4)
oTbl.Rows.Last.Cells(2).Range.Text = xlSh.Cells(i, 5)
Set oTbl = Nothing

Dans ce petit morceau, on affecte à la variable Table le premier tableau du document. Nous allons ajouter une ligne à cette table et remplir cette ligne avec certaines données.

Else
Set oTbl = oDoc.Tables(1)
oTbl.Rows.Add
oTbl.Rows.Last.Cells(1).Range.Text = xlSh.Cells(i, 4)
oTbl.Rows.Last.Cells(2).Range.Text = xlSh.Cells(i, 5)
Set oTbl = Nothing
oDoc.Save
End If

Le code est utilisé deux fois, la seconde est utilisée pour n'ajouter des données qu'à la table et plus dans le corps du document.

Pour les fichiers ci-dessous, il suffit de mettre tous les fichiers dans le même répertoire. La macro est contenue dans le fichier "DocumentPrincipal". Téléchargez des fichiers exemples

IX - Liens

Le lien suivant vous conduit vers un tutoriel sur le publipostage, mais au lieu d'utiliser Word, on utilise Access.
https://heureuxoli.developpez.com/publipostage/

Un tutoriel sur le publipostage avec Excel :
https://silkyroad.developpez.com/Excel/PublipostageWordExcel/

L'utilisation du DAO :
Définition et manipulation de données avec DAO

L'utilisation de l'ADO :
L'ADO

X - Conclusions et remerciements

Nous venons d'aborder quelques méthodes utilisées pour le publipostage sous Word. J'espère que vous pourrez y trouver une solution qui vous convient.

Je tiens à remercier Antoun et claudeLELOUP qui en plus d'une correction orthographique ont aussi fait une correction du fond et de la forme de cet article.
Un grand merci à DVP, ses membres et à l'équipe Office.