Débutez en VBA Word

Cette propriété en lecture seule renvoie le document actif.

Sub CheminDocumentActif()
Debug.Print Application.ActiveDocument.FullName
End Sub

Comme mentionné plus tôt, nous aurions pu écrire :

Sub CheminDocumentActif()
Debug.Print ActiveDocument.FullName
End Sub

Cette propriété renvoie le nom de l'imprimante active du système, cette propriété est en lecture/écriture.

Sub NomImprimante()
Debug.Print Application.ActivePrinter
End Sub

Ce code n'a aucun intérêt, par contre, mémoriser le nom de l'imprimante active, attribuer une nouvelle imprimante pour un travail particulier et restaurer l'imprimante par défaut ensuite peut s'avérer très intéressant.

Sub ChangerImprimante()
'Déclaration des variables
Dim strOldPrinter As String
'Récupération du nom de l'imprimante active
strOldPrinter = Application.ActivePrinter
'Changement de l'imprimante
Application.ActivePrinter = "PDF Creator"
'Impression
ActiveDocument.PrintOut
'Attendre la fin de l'impression
DoEvents
'Restaurer l'imprimante de départ
ActivePrinter = strOldPrinter

End Sub

Cette propriété vous permet de modifier le titre contenu dans la barre de titre de Word. Si vous voulez donner une touche personnelle à Word, cette propriété vous permettra d'y parvenir.

Sub ChangerTitreBarre()
Application.Caption = "www.developpez.com"
End Sub

Propriété en lecture/écriture autorisant ou non l'affichage des fichiers récents.

Sub AfficherFichiersRecents()
Application.DisplayRecentFiles = False
End Sub

Supprimer l'affichage efface le contenu de la liste, même si on le rétablit ensuite.

Renvoie un objet FileDialog qui représente une instance unique d'une boîte de dialogue Fichier. Cette propriété est très utile lorsque vous devez choisir un fichier ou un répertoire.

Sub AfficherFileDialog()
Dim dlg As FileDialog
Dim strPath As String

Set dlg = Application.FileDialog(msoFileDialogFolderPicker)
With dlg
    .InitialFileName = "C:\temp\"
    .AllowMultiSelect = False
    .Title = "www.developpez.com"
    .Show
End With

strPath = dlg.SelectedItems(1)

Set dlg = Nothing

End Sub

Il existe quatre types de FileDialog :

Lorsque vous utilisez l'objet FileDialog, vous pouvez spécifier si l'utilisateur pourra sélectionner plusieurs fichiers ou un seul à la fois; vous pouvez églement spécifier un répertoire de départ.

Dans l'exemple que je viens de donner, vous aurez probablement remarqué la présence d'un With.....End With. Cette structure permet pour un même objet d'exécuter une série d'instructions :

With dlg
    .InitialFileName = "C:\temp\"
    .AllowMultiSelect = False
    .Title = "www.developpez.com"
    .Show
End With

est équivalent à :

dlg.InitialFileName = "C:\temp\"
dlg.AllowMultiSelect = False
dlg.Title = "www.developpez.com"
dlg.Show

Exercice :
Créez une fonction qui va ouvrir un objet FileDialog, passez en argument le titre de votre boîte de dialogue ainsi que le répertoire de départ. Cette fonction renverra le nom du fichier choisi.

Nous n'avons utilisé qu'un seul élément sélectionné dans notre liste, si vous le spécifiez, vous pouvez autoriser une sélection multiple. Ci-dessous, vous trouverez un exemple de code pour une sélection multiple et la façon de récupérer les différents éléments choisis.

Sub ListeSelectionMultiple()
Dim oDlg As FileDialog
Dim varSelected As Variant

Set oDlg = Application.FileDialog(msoFileDialogFilePicker)
With oDlg
    .AllowMultiSelect = True
    .Show
End With

For Each varSelected In oDlg.SelectedItems
    Debug.Print varSelected
Next varSelected

Set oDlg = Nothing

End Sub

La première partie reste la même, seule la récupération diffère. La variable qui va être utilisée pour la récupération des éléments doit être du type Variant. Ensuite, on récupère chaque élément à l'aide d'une boucle.
La valeur récupérée renvoie le chemin complet des fichiers sélectionnés.

Cette propriété renvoie le modèle Normal, communément appelé "Normal.dot"

Sub CheminDuNormalPointDot()
Debug.Print Application.NormalTemplate.FullName
End Sub

Ce code vous donne le chemin complet du normal.dotm.

Cette propriété donne accès aux différentes options de l'environnement de Word. Vous trouverez ci-dessous quelques options disponibles, la liste complète est très longue.

Sub OptionsDeWord()
With Application.Options
    .AllowDragAndDrop = False
    .AllowReadingMode = True
    .AutoFormatAsYouTypeReplaceHyperlinks = True
    .CheckGrammarAsYouType = True
    .IgnoreUppercase = True
End With
End Sub

Cette propriété permet de geler l'affichage lorsqu'on lui affecte la valeur False.

Cette propriété est particulièrement intéressante si vous travaillez avec l'objet Selection.

Application.ScreenUpdating = False
...
...
Application.ScreenUpdating = True

Si vous voulez obtenir un rafraichissement occasionnel de l'affichage utilisez :

Application.ScreenRefresh

Cette propriété permet de récupérer quelques informations sur le système, le type d'OS, l'espace disque disponible ...

Sub ProprietesSystem()
With Application.System
    Debug.Print .OperatingSystem 'Version OS installée
    Debug.Print .HorizontalResolution 'Résolution verticale
    Debug.Print .VerticalResolution 'Résolution horizontale
End With
End Sub

Vous remarquerez que l'on peut dans une structure With ... End With ajouter des fonctions comme un Debug.Print dans l'exemple ou une affectation à une variable.

Cette propriété permet détermine si l'objet application est visible ou pas. Elle principalement utilisée lorsque l'on utilise Word à partir d'une autre application.

Par défaut, si vous ne spécifiez pas de répertoire lorsque vous tentez d'ouvrir un fichier, c'est l'endroit où Word va chercher. Il est possible de modifier ce répertoire.

Sub ModifierCheminParDefaut()
Application.ChangeFileOpenDirectory "C:\temp\"
End Sub

Exercice :
Avec ce que nous avons vu précédemment, changez le répertoire par défaut et ensuite, restaurez-le.

Ne pas confondre ChangeFileOpenDirectory et DefaultFilePath l'un est volatile alors que le second est permanent. Le changement produit par le premier s'estompe lorsque Word est fermé.

Si vous craignez de rester trop longtemps au boulot, cette propriété est pour vous.
Pour son utilisation, vous avez deux possibilités, soit vous utilisez une heure précise soit vous spécifiez un délai.

La méthode OnTime permet de lancer une routine à un moment prédéterminé.

Application.Ontime When:="16:00:00", Name:="MaProcedure"

Application.Ontime When:=Now + TimeValue("00:10:00"), Name:="MaProcédure"

L'argument When est passé en format texte.

C'est la méthode qui possède le nom le plus clair. Cette méthode ferme l'application; n'oubliez pas de libérer l'instance de votre objet une fois que vous avez quitté l'application.

Application.Quit

Exercice :
En vous basant sur les fonctions VBA pour la création d'un objet, déclarez un objet Word, affectez-lui une valeur et fermez le tout.

Deux méthodes seront abordées pour la gestion des événements. Vous pouvez utiliser un module de classe ou directement dans votre module "ThisDocument". En utilisant un module de classe, vous pouvez réutiliser votre code à souhait sans devoir l'écrire pour chacun de vos projets.

II-C-1-a. Module de classe▲

Pour la gestion des événements, nous devons créer un module de classe pour y déclarer un objet application pour la gestion des événements.

Vous aller renommer ce module en EventClassModule.

Nous allons déclarer notre application

Déclaration de notre objet application

Sélectionnez

Public WithEvents appWord As Word.Application

WithEvents : mot clé indiquant que l'argument varname est une variable objet utilisée pour répondre aux événements déclenchés par un objet ActiveX. Valide uniquement dans des modules de classe.

Dès que votre objet Application est déclaré, les événements sont disponibles dans la liste.

Si vous choisissez l'objet Application, vous pouvez choisir un événement qui lui est associé.

Les événements liés à l'application doivent se trouver dans le module de classe.

II-C-1-b. Initialisation du module de classe▲

Dim MyApp As New EventsClassModule
Sub Document_New()
Set MyApp.appWord = Word.Application
End Sub

II-C-1-c. Directement dans votre module (sans module de classe)▲

Public WithEvents App As Word.Application

Sub Document_Open()
Set App = Word.Application
End Sub

Public WithEvents App As Word.Application

Sub document_open()
Set App = Word.Application
End Sub
 
Private Sub App_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)
MsgBox "Avant sauvegarde"
End Sub

Cet événement se produit juste avant la fermeture d'un document.

Private Sub appWord_DocumentBeforeClose(ByVal Doc As Document, Cancel As Boolean)
...
End Sub

La valeur de l'argument Cancel déterminera si le document sera fermé ou non, si elle est True, le document restera ouvert.

Se produit lors du changement de document actif.

Private Sub appWord_DocumentChange()
    MsgBox "Doc Changé"
End Sub

Cette propriété permet de connaître le nombre de documents ouverts. Elle est très simple d'utilisation.

Sub NombreDeDocuments()
    Debug.Print Documents.Count
End Sub

La propriété Count peut être appliquée sur toutes les collections, elle renvoie le nombre d'éléments ouverts composant cette collection.

Cette méthode va ouvrir un document pour l'ajouter à la collection "Documents".

Sub OuvrirDocument()
    Documents.Open "C:\Temp\mondocument.dotx"
end Sub

Si vous désirez créer un nouveau document, vous devez ajouter un document à la collection et utiliser la méthode Add.

Sub AjouterDocument()
    Documents.Add
End Sub

Si vous ne passez pas d'argument à la méthode, c'est un nouveau document basé sur le modèle normal qui sera créé. Vous pouvez spécifier un modèle de document pour votre méthode en passant son chemin en argument.

Sub AjouterDocument()
Documents.Add "C:\Temp\DVP.Dotm"

End Sub

Comme elle s'applique à la collection, cette méthode permet de sauvegarder tous les documents ouverts.

Sub SauvegarderDocuments()
    Documents.Save
End Sub

Tous les documents.

Appliquée à la collection, cette méthode ferme tous les documents ouverts.

Sub DocumentsClose()
Documents.Close
End Sub

Les méthodes les plus importantes sont utilisées au niveau de la collection, Open et Add qui renvoient toutes deux un document.

Set objDoc1 = Documents.Open ("C:\Temp\MonDoc1.docm")

III-C-1-a. Save▲

Sub SauvegarderDoc()
'Sauvegarde du document actif
ActiveDocument.Save

End Sub

III-C-1-b. SaveAs▲

Sub SauverAvecNom()
ActiveDocument.SaveAs

End Sub

Sub SauverAvecNom()
ActiveDocument.SaveAs FileName:="C:\temp\MonDocument.docm"

End Sub

III-C-1-c. Goto▲

Sub Atteindre()
ActiveDocument.Goto What:=wdGotoPage, Which:=wdGoToAbsolute, Count:=5
End Sub

III-C-1-d. PrintOut▲

Sub ImprimerDocument()
ActiveDocument.PrintOut
End Sub

III-C-1-e. Convert▲

Sub DocumentUpgrade()
ActiveDocument.Convert

End Sub

III-C-2-a. Saved▲

Sub PasDeMessage()
ActiveDocument.Saved = True

End sub

III-C-2-b. Content▲

Sub ContenuDuDocument()
Debug.Print ActiveDocument.Content
End Sub

III-C-2-c. FullName, Name, Path▲

Sub CheminEtNom()
With ActiveDocument
    Debug.Print .Name
    Debug.Print .Path
    Debug.Print .FullName
End With
End Sub

III-C-2-d. AttachedTemplate▲

Sub ModeleAttache()
    Debug.Print ActiveDocument.AttachedTemplate
End Sub

III-C-2-e. Paragraphs▲

Sub NombreDeParagraphes()
    Debug.Print ActiveDocument.Paragraphs.Count
End Sub

III-C-2-f. Sentences▲

Sub NombreDeParagraphes()
    Debug.Print ActiveDocument.Sentences.Count
End Sub

III-C-2-g. Sections▲

Sub NombreDeParagraphes()
    Debug.Print ActiveDocument.Sections.Count
End Sub

III-C-2-h. Shapes▲

Sub NombreDeParagraphes()
    Debug.Print ActiveDocument.Shapes.Count
End Sub

III-C-2-i. InlineShapes▲

Sub NombreDeParagraphes()
    Debug.Print ActiveDocument.InlineShapes.Count
End Sub

Les évènements liés aux documents sont plus faciles à mettre en oeuvre que pour l'application.

Nous n'allons en citer que quelques-uns et donner un seul exemple.

Évènements des documents

• Close - Se produit à la fermeture d'un document
• Open - Se produit sur l'ouverture d'un document
• New - Se produit lors de la création d'un nouveau document

Sub Document_Open()
...
...
End Sub

Ce code sera exécuté lors de chaque ouverture de votre document.

Pour récupérer l'index d'un paragraphe, il est nécessaire de ruser.
Dans le code ci-dessous, nous partons du point d'insertion, nous étendons la sélection jusqu'au début du document, il ne nous reste qu'à compter le nombre de paragraphes que la sélection contient.

Sub RecuperationIndexPara()

Selection.HomeKey Unit:=wdStory, Extend:=wdExtend
Debug.Print Selection.Paragraphs.Count


End Sub

Comme déjà mentionné, le style ainsi que la police de caractère ne sont pas appliqués aux paragraphes mais aux données qu'ils contiennent.

Sub AppliquerStyle()
ActiveDocument.Paragraphs(1).Range.Style = "Titre 1"

End Sub

Pour appliquer un style, vous avez plusieurs possibilités pour le nom du style. Vous pouvez utiliser le nom qui apparait dans la galerie des styles, dans notre exemple "Titre 1", ou utiliser une constante Word : wdStyleHeading1.

De la même manière nous pouvons récupérer le style appliqué au paragraphe :

Sub RecupererStyle()
Debug.Print ActiveDocument.Paragraphs(1).Range.Style

End Sub

Si vous appliquez le style au paragraphe et pas à son contenu, vous ne rencontrerez pas de problème, mais par habitude travaillez avec l'objet Range.

Dans la même optique, vous pouvez modifier la police de caractère d'un paragraphe sans passer par les styles.

Sub ModifierPolice()
With ActiveDocument.Paragraphs(3).Range.Font
    .Name = "Arial"
    .Bold = True
    .StrikeThrough = True
End With

End Sub

Nous l'avons vu plus tôt, With permet d'appliquer à un même objet plusieurs instructions. Instruction With ... End With

Pour parcourir les paragraphes d'un document, nous allons avoir besoin d'utiliser une boucle.
Les boucles

Les paragraphes (Paragraph) font partie de la collection Paragraphs, nous allons utiliser une boucle For Each ... Next.

Sub ParcourirParagraphes()
'Déclaration de l'objet paragraphe
Dim pAra As Paragraph
'Comme nous allons parcourir la collection, il n'est pas utile d'utiliser
'l'opérateur d'affectation Set
For Each pAra In ActiveDocument.Paragraphs
    Debug.Print Len(pAra.Range.Text)
Next pAra

End Sub

La variable pAra a volontairement été écrite avec une majuscule en seconde position. De cette manière, lorsque vous saisissez le nom de la variable en minuscule, le VBE corrige automatiquement et vous êtes certain que le nom de variable a été reconnu.

Un paragraphe peut contenir des phrases Sentences. Créez un document vierge, tapez : =rand(1,10) suivi Enter pour ensuite essayer ce code.

Sub CompterPhrases()
Debug.Print ActiveDocument.Paragraphs(1).Range.Sentences.Count
End Sub

Vous devriez obtenir 10. Ce code compte le nombre de phrases contenues dans le premier paragraphe du document.

Malheureusement, les mots ne sont pas des objets en Word, mais malgré tout, il existe une collection Words qui représente les mots contenus dans une portion du document.

Sub CompterMots()
Debug.Print ActiveDocument.Paragraphs(1).Range.Words.Count
End Sub

Exercice :
Dans ce même morceau de document, vous allez compter le nombre de mots dans chaque phrase du premier paragraphe.
Attention, l'objet Word n'existe pas, vous devrez le déclarer en tant que Variant.

Exercice :
Créez un nouveau document, remplissez le avec : =rand(10,2), supprimez le dernier paragraphe vide
Mettez en gras et double souligné le troisième mot de chaque paragraphe.

De la même manière qu'avec les autres collections, la méthode Add va ajouter un paragraphe.

Sub AjouterParagraph()

ActiveDocument.Paragraphs.Add Range:=Paragraphs(3).Range

End Sub

L'argument Range passé à la méthode peut être omis et dans ce cas, le paragraphe est ajouté au point d'insertion.

Sub AjouterParagraph()

ActiveDocument.Paragraphs.Add

End Sub

Il existe une méthode de l'objet Selection qui produit le même effet :

Sub AjouterParagraphe()
Selection.InsertParagraph
End Sub

Cette méthode ajoute un interligne Simple, de 1,5 ou double aux paragraphes spécifiés.
La mise en oeuvre est assez simple :

ActiveDocument.Paragraphs.Space15

Cette méthode peut s'appliquer à la collection ou à un membre de la collection.

ActiveDocument.PAragraphs(1).Space2

Ces deux propriétés sont similaires, seule leur action est différente. Dans le cas de Promote, on va changer le niveau de titre des paragraphes spécifiés pour monter le niveau de titre de 1 et pour Demote, on va diminuer le niveau de titre de 1.

Si vous avez un paragraphe de niveau de titre 2 et que vous lui appliquez la méthode OutlinePromote, vous aurez un paragraphe de niveau de titre 1.
De la même manière, la méthode OutlineDemote va diminuer le niveau de titre de 1, si vous appliquez cette méthode à un paragraphe de titre 2, vous obtiendrez un titre de niveau 3.

Il est beaucoup plus facile d'attribuer un style de titre que de passer par cette méthode.

ActiveDocument.Paragraphs(4).OutlineDemote

Cette propriété permet l'alignement du paragraphe, vous avez plus de possibilités qu'avec l'interface graphique.

ActiveDocument.Paragraphs(1).Alignment = wdAlignParagraphRight

Alignment peut prendre les valeurs ci-dessous :

Ajoute des bordures au paragraphe spécifié. Un exemple sera plus intéressant qu'une description :

Sub AjouterBordure()
'Ajoute les bordures au paragraphe
With ActiveDocument.Paragraphs(6)
    .Borders(wdBorderLeft).Visible = True
    .Borders(wdBorderBottom).Visible = True
    .Borders(wdBorderTop).Visible = True
    .Borders(wdBorderRight).Visible = True
End With
'Modifie l'aspect de la bordure
With ActiveDocument.Paragraphs(6).Borders
    .OutsideLineStyle = wdLineStyleDashDot
End With

End Sub

Comme pour beaucoup d'objets, la méthode pour ajouter est Add.

Sub AjouterTableau()
ActiveDocument.Tables.Add Range:=Selection.Range, numrows:=5, numcolumns:=6
End Sub

Cette table de 5 lignes et 6 colonnes sera ajoutée à l'emplacement du curseur de la souris.

Exercice
Vous allez sur le document actif créer une table de 3 colonnes et 3 lignes.
Par le code, vous allez créer un nouveau document dans lequel vous allez ajouter une table contenant le même nombre de lignes et de colonnes.

En Word, un tableau ou table est constitué de lignes et de colonnes, vous avez utilisé l'exercice précédent deux arguments pour ces objets. Vous pouvez récupérer le nombre de lignes et de colonnes de votre tableau en utilisant la propriété Count.

Sub AfficherLignesEtColonnes()
Dim intR As Integer
Dim intC As Integer
Dim strMessage As String
'Récupération du nombre de lignes et de colonnes
intR = ActiveDocument.Tables(1).Rows.Count
intC = ActiveDocument.Tables(1).Columns.Count
'Élaboration du message par concaténation
strMessage = "Votre tableau contient : " & vbCrLf
strMessage = strMessage & intC & " colonnes " & vbCrLf
strMessage = strMessage & intR & " lignes."
'Affichage du message
MsgBox strMessage

End Sub

Pour ajouter une ligne ou une colonne à un tableau, nous allons procéder de la même façon, mais nous allons utiliser la méthode Add au lieu de la propriété Count.

Sub AjouterLigneEtColonne()
Dim oTbl As Table

Set oTbl = ActiveDocument.Tables(1)
oTbl.Rows.Add 
oTbl.Columns.Add 
Set oTbl = Nothing
End Sub

Ce code va simplement ajouter une ligne et une colonne, à la fin de votre tableau pour la ligne et à la droite pour la colonne. Ce serait beaucoup plus intéressant de pouvoir ajouter cette ligne ou cette colonne à un endroit de votre choix.
La méthode Add peut prendre un argument pour l'ajout.

Sub AjouterLigneEtColonne()
Dim oTbl As Table

Set oTbl = ActiveDocument.Tables(1)
oTbl.Rows.Add BeforeRow:=oTbl.Rows(2)
oTbl.Columns.Add BeforeColumn:=oTbl.Columns(2)
Set oTbl = Nothing
End Sub

Dans l'exemple ci-dessus, nous ajoutons une ligne avant la seconde et pareil pour la colonne. La seule difficulté est la valeur passée à l'argument, ce n'est pas un entier, mais un objet ligne ou colonne.

Lorsque vous ajoutez ou utilisez un tableau dans un document, vous pouvez aussi ajouter des données dans les cellules. Pour le faire, la méthode est assez simple, il suffit d'adresser cette cellule et d'affecter les données au Range de la cellule

ActiveDocument.Tables(1).Cell(1,1).Range.Text = "Mon Texte"

Pour récupérer le contenu d'une cellule, la méthode est la même que pour l'ajout de données.

Debug.Print ActiveDocument.Tables(1).Cell(1,1).Range.Text

Nous avons vu comment ajouter un contenu à une cellule et un exercice pour le récupérer. Lors de cette récupération, vous aurez probablement remarqué que le texte récupéré est plus long que le texte ajouté. Ce phénomène est dû aux caractères non imprimables qui délimitent la cellule. Pour remédier à cet inconvénient, nous allons fabriquer une petite fonction utilisant certaines fonctions que nous avons vues dans les chapitres précédents, Len et Left.

Nous allons récupérer le contenu, mesurer sa taille en comptant le nombre de caractères présents et nous allons prendre tous les caractères sans les deux derniers. Nous allons appeler cette fonction NetText et lui passer en paramètre le texte contenu dans la cellule qui est à traiter.

Public Function NetText(stTemp As String) As String
'Nous utilisans les caractères de la chaîne sans les deux derniers
NetText = Left( stTemp , Len(stTemp) - 2 )
End Sub

Souvenez-vous de cette fonction, vous en aurez certainement besoin.

L'utilisation de l'ensemble est assez simple :

Debug.Print NetText(ActiveDocument.Tables(1).Cell(1,1).Range.Text)

Il est fréquent que l'on doive d'ajouter une ligne à un table pour y injecter des données. Pour y parvenir, nous allons utiliser la méthode Add et ensuite la propriété Count pour obtenir le nombre de ligne, de cette manière, nous pourrons adresser la dernière.

Sub AjouterLigneEtDonnees()
Dim oTbl As Table

Set oTbl = ActiveDocument.Tables(1)
oTbl.Rows.Add
oTbl.Rows(oTbl.Rows.Count).Cell(1).Range.Text = "Dernière Ligne"
Set oTbl = Nothing
End Sub

Exercice
Nous avons vu comment ajouter un tableau à un document et comment adresser les cellules de ce tableau.
Vous allez créer un nouveau document, y ajouter un table qui sera une table de multiplication pour les nombres de 1 à 10, et 20 valeurs pour les nombres. Vous ajouterez des titres aux colonnes et aux lignes.

En plus d'un contenu, le Range de la cellule possède des attributs permettant de définir le format du texte contenu et de la cellule elle-même.

Vous aurez probablement remarqué que, lorsque vous insérez un tableau dans un document, toutes les lignes sont transparentes. Le code ci-dessous va ajouter une bordure au tableau et définir des lignes pour border les cellules.

Sub AjouterContour()
Dim oTbl As Table

Set oTbl = ActiveDocument.Tables(1)

With oTbl.Borders
    .Enable = True
    .InsideLineStyle = wdLineStyleDot
    .OutsideLineStyle = wdLineStyleSingle
    .InsideLineWidth = wdLineWidth050pt
    .OutsideLineWidth = wdLineWidth100pt
End With

End Sub

Le texte que vous allez insérer aura le format par défaut des cellules, mais vous pouvez modifier le format du texte contenu dans une cellule.

With oTbl.Rows(1).Range.Font
    .Bold = True
    .Underline = wdUnderlineDouble
    .UnderlineColor = wdColorBrightGreen
End With

Nous avons déjà utilisé cette méthode, elle permet l'ajout d'une table à la collection des tables du document.

ActiveDocument.Tables.Add Range:=Selection.Range, numrows:=5, numcolumns:=6

Les trois arguments ne sont pas facultatifs, Range représente l'endroit où la table sera ajoutée, numrows le nombre de lignes et numcolumns le nombre de colonnes.

Sans aucune surprise, cette méthode va supprimer une table de votre document.

ActiveDocument.Tables(1).Delete

Cette méthode va sélectionner une table de votre document. Vous pourrez ensuite utiliser l'objet Selection pour effectuer certaines actions.

ActiveDocument.Tables(1).Select
Selection.Copy
Documents.Add
ActiveDocument.Select
Selection.Paste

Méthode intéressante, elle permet de trier le contenu d'une table. Il existe trois méthodes de tri pour une table :

• SortAscending
• SortDescending
• Sort

Les deux premières méthodes permettent un tri rapide d'une table. Le tri sera croissant ou décroisant selon que l'on utilise l'un ou l'autre. Leur utilisation est simple et ne comporte pas d'argument.

Sub TriTable()
ActiveDocument.Tables(1).SortDescending

End Sub

La première ligne de la table est systématiquement exclue du tri avec ces deux méthodes.

La méthode Sort est un peu plus complexe, mais plus puissante. Vous pouvez avec cette méthode effectuer un tri sur plusieurs colonnes, inclure la première ligne dans votre tri, etc.

La propriété la plus universelle s'applique aussi aux tables d'un document, elle va renvoyer le nombre d'objets de la collection.

debug.Print ActiveDocument.Tables.Count

Si vous voulez redimensionner un tableau en fonction de son contenu, c'est la propriété que vous devez utiliser.

ActiveDocument.Tables(1).AllowAutofit

Il est très embêtant de voir un tableau coupé en deux par un saut de page. Lorsque cette propriété est sur False, votre tableau sera en un seul morceau tant que c'est possible. En effet, si votre tableau fait plusieurs pages, vous n'aurez pas d'autre solution que de le scinder.

ActiveDocument.Tables(1).AllowPageBreaks = False

Vous aurez probablement remarqué que le tableau que vous insérez via le code n'est qu'une grille sans bordures. Si vous voulez des bordures à votre tableau, vous devez les ajouter.

Sub AjoutTableau()
Dim oTbl As Table

Set oTbl = ActiveDocument.Tables.Add(Range:=Selection.Range, NumRows:=5, Numcolumns:=5)
With oTbl.Borders
    .InsideLineStyle = wdLineStyleDouble
    .InsideLineWidth = wdLineWidth025pt
    .OutsideLineStyle = wdLineStyleSingleWavy
End With
Set oTbl = Nothing
End Sub

L'utilisation de l'IntelliSense nous facilite la vie pour le choix des constantes à renseigner dans le code.

Cette propriété renvoie la partie du document contenue dans un tableau.

Sub TablesRange()
Debug.Print ActiveDocument.Tables(2).Range.Text
End Sub

Ce code va renvoyer le contenu de toutes les cellules de votre tableau.

Cette propriété peut paraître déplacée, mais une table peut contenir une autre table.

Sub AjouterTables()
Dim oTbl As Table
Set oTbl = ActiveDocument.Tables.Add(Range:=Selection.Range, numrows:=2, numcolumns:=2)
oTbl.Cell(1, 1).Select

Selection.Tables.Add Range:=Selection.Range, numrows:=1, numcolumns:=2
End Sub

Cette méthode permet de savoir si le signet existe dans la collection.

If ActiveDocument.Bookmarks.Exists("S1") Then
    ActiveDocument.Bookmarks("S1").Delete
End If

Cette méthode renvoie la valeur True si le signet existe.

Nous l'avons abordée dans l'exemple précédent. Un signet peut être supprimé par ce code.

ActiveDocument.Bookmarks("S1").Delete

Nous avons déjà fait appel à cette propriété dans notre exemple :

ActiveDocument.Bookmarks.Add stBM, MyRng

Cette méthode prend deux arguments, le premier (Name:=) est le nom du signet et le second (Range:=), la plage de données qui sera utilisée pour le signet, cette plage peut se résumer à un point d'insertion.

Cette méthode permet de vérifier l'existence d'un signet. Si le signet existe, l'expression renvoie Vrai, Faux dans le cas contraire.

ActiveDocument.Bookmarks.Exists("S1")
' Avec S1 comme nom de signet

Cette méthode ne s'utilise qu'avec le nom du signet.

C'est probablement la propriété la plus célèbre, elle permet de connaître le nombre de signets contenu dans la collection des signets (Bookmarks).

Debug.Print ActiveDocument.Bookmarks.Count

Cette propriété renvoie le nom du signet, cette propriété est en lecture écriture, nous l'avons déjà utilisée pour notre exemple.

Debug.Print ActiveDocument.Bookmarks(1).Name